Visual Basic Graphics Programming (2nd Edition)/Visual Basic Graphics Programming 2nd Edition.iso/OldSrc/CH10/SRC/EXTRUDE.FRM

Visual Basic Form | 1996-05-02 | 19.5 KB | 638 lines

VERSION 4.00
Begin VB.Form ExtrudeForm
   Appearance      =   0  'Flat
   BackColor       =   &H00C0C0C0&
   Caption         =   "Extrude"
   ClientHeight    =   5700
   ClientLeft      =   690
   ClientTop       =   900
   ClientWidth     =   7830
   BeginProperty Font
      name            =   "MS Sans Serif"
      charset         =   1
      weight          =   700
      size            =   8.25
      underline       =   0   'False
      italic          =   0   'False
      strikethrough   =   0   'False
   EndProperty
   ForeColor       =   &H80000008&
   Height          =   6390
   KeyPreview      =   -1  'True
   Left            =   630
   LinkTopic       =   "Form1"
   ScaleHeight     =   380
   ScaleMode       =   3  'Pixel
   ScaleWidth      =   522
   Top             =   270
   Width           =   7950
   Begin VB.CommandButton CmdExtrude
      Caption         =   "Extrude"
      Height          =   495
      Left            =   720
      TabIndex        =   11
      Top             =   5040
      Width           =   855
   End
   Begin VB.Frame Frame2
      Caption         =   "Curve"
      Height          =   2415
      Left            =   0
      TabIndex        =   10
      Top             =   0
      Width           =   2295
      Begin VB.OptionButton CurveChoice
         Caption         =   "Sine Wave"
         Height          =   255
         Index           =   5
         Left            =   120
         TabIndex        =   22
         Top             =   2040
         Width           =   2055
      End
      Begin VB.OptionButton CurveChoice
         Caption         =   "Small Circle"
         Height          =   255
         Index           =   4
         Left            =   120
         TabIndex        =   21
         Top             =   1680
         Width           =   2055
      End
      Begin VB.OptionButton CurveChoice
         Caption         =   "Circle"
         Height          =   255
         Index           =   3
         Left            =   120
         TabIndex        =   20
         Top             =   1320
         Width           =   2055
      End
      Begin VB.OptionButton CurveChoice
         Caption         =   "Semicircle"
         Height          =   255
         Index           =   2
         Left            =   120
         TabIndex        =   19
         Top             =   960
         Width           =   2055
      End
      Begin VB.OptionButton CurveChoice
         Caption         =   "Rectangle"
         Height          =   255
         Index           =   1
         Left            =   120
         TabIndex        =   18
         Top             =   600
         Width           =   2055
      End
      Begin VB.OptionButton CurveChoice
         Caption         =   "Square"
         Height          =   255
         Index           =   0
         Left            =   120
         TabIndex        =   12
         Top             =   240
         Value           =   -1  'True
         Width           =   2055
      End
   End
   Begin VB.Frame Frame1
      Caption         =   "Path"
      Height          =   2415
      Left            =   0
      TabIndex        =   8
      Top             =   2520
      Width           =   2295
      Begin VB.OptionButton PathChoice
         Caption         =   "Circle"
         Height          =   255
         Index           =   5
         Left            =   120
         TabIndex        =   17
         Top             =   2040
         Width           =   2055
      End
      Begin VB.OptionButton PathChoice
         Caption         =   "Semicircle"
         Height          =   255
         Index           =   4
         Left            =   120
         TabIndex        =   16
         Top             =   1680
         Width           =   2055
      End
      Begin VB.OptionButton PathChoice
         Caption         =   "Helix"
         Height          =   255
         Index           =   3
         Left            =   120
         TabIndex        =   15
         Top             =   1320
         Width           =   2055
      End
      Begin VB.OptionButton PathChoice
         Caption         =   "Wavy Line"
         Height          =   255
         Index           =   2
         Left            =   120
         TabIndex        =   14
         Top             =   960
         Width           =   2055
      End
      Begin VB.OptionButton PathChoice
         Caption         =   "Angled Line"
         Height          =   255
         Index           =   1
         Left            =   120
         TabIndex        =   13
         Top             =   600
         Width           =   2055
      End
      Begin VB.OptionButton PathChoice
         Caption         =   "Vertical Line"
         Height          =   255
         Index           =   0
         Left            =   120
         TabIndex        =   9
         Top             =   240
         Value           =   -1  'True
         Width           =   2055
      End
   End
   Begin VB.CheckBox ShowAxesCheck
      Caption         =   "Show Axes"
      Height          =   255
      Left            =   2400
      TabIndex        =   7
      Top             =   5400
      Width           =   1335
   End
   Begin VB.TextBox PhiText
      Height          =   285
      Left            =   6960
      TabIndex        =   6
      Text            =   "0.1570"
      Top             =   5400
      Width           =   855
   End
   Begin VB.TextBox ThetaText
      Height          =   285
      Left            =   5640
      TabIndex        =   4
      Text            =   "0.6283"
      Top             =   5400
      Width           =   855
   End
   Begin VB.TextBox RText
      Height          =   285
      Left            =   4080
      TabIndex        =   2
      Text            =   "10"
      Top             =   5400
      Width           =   855
   End
   Begin VB.PictureBox Pict
      AutoRedraw      =   -1  'True
      Height          =   5295
      Left            =   2400
      ScaleHeight     =   349
      ScaleMode       =   3  'Pixel
      ScaleWidth      =   357
      TabIndex        =   0
      Top             =   0
      Width           =   5415
   End
   Begin MSComDlg.CommonDialog LoadDialog
      Left            =   1680
      Top             =   5040
      _version        =   65536
      _extentx        =   847
      _extenty        =   847
      _stockprops     =   0
      cancelerror     =   -1  'True
   End
   Begin VB.Label Label1
      Caption         =   "Phi"
      Height          =   255
      Index           =   2
      Left            =   6600
      TabIndex        =   5
      Top             =   5415
      Width           =   375
   End
   Begin VB.Label Label1
      Caption         =   "Theta"
      Height          =   255
      Index           =   1
      Left            =   5040
      TabIndex        =   3
      Top             =   5415
      Width           =   495
   End
   Begin VB.Label Label1
      Caption         =   "R"
      Height          =   255
      Index           =   0
      Left            =   3840
      TabIndex        =   1
      Top             =   5415
      Width           =   255
   End
   Begin VB.Menu mnuFile
      Caption         =   "&File"
      Begin VB.Menu mnuFileLoad
         Caption         =   "&Load..."
         Shortcut        =   ^L
      End
      Begin VB.Menu mnuFileSaveAs
         Caption         =   "&Save As..."
         Shortcut        =   ^A
      End
      Begin VB.Menu mnuFileSep
         Caption         =   "-"
      End
      Begin VB.Menu mnuFileExit
         Caption         =   "E&xit"
      End
   End
Attribute VB_Name = "ExtrudeForm"
Attribute VB_Creatable = False
Attribute VB_Exposed = False
Option Explicit
' Location of viewing eye.
Dim EyeR As Single
Dim EyeTheta As Single
Dim EyePhi As Single
Const dtheta = PI / 20
Const Dphi = PI / 20
Const Dr = 1
' Location of focus point.
Const FocusX = 0#
Const FocusY = 0#
Const FocusZ = 0#
Dim Projector(1 To 4, 1 To 4) As Single
Dim CurveNum As Integer
Dim PathNum As Integer
Dim ThePicture As ObjPicture
Dim TheExtrusion As ObjExtrusion
Dim ShowingParameters As Boolean
' ************************************************
' Create the selected path.
' ************************************************
Sub CreatePath()
Dim y As Single
Dim R As Single
Dim dtheta As Single
Dim theta As Single
    Select Case PathNum
        Case 0  ' Vertical line.
            For y = 0 To 4 Step 0.5
                TheExtrusion.AddPathPoint 0, y, 0
            Next y
        Case 1  ' Angled line.
            For y = 0 To 4 Step 0.5
                TheExtrusion.AddPathPoint y / 2, y, y / 2
            Next y

        Case 2  ' Wavy line.
            R = 2
            dtheta = PI / 5
            TheExtrusion.AddPathPoint 0, 0, 0
            For theta = dtheta To 2 * PI Step dtheta
                TheExtrusion.AddPathPoint _
                    R * Sin(theta), theta * 0.7, 0
            Next theta

        Case 3  ' Helix.
            R = 2
            dtheta = PI / 10
            TheExtrusion.AddPathPoint R, 0, 0
            For theta = dtheta To 2 * PI Step dtheta
                TheExtrusion.AddPathPoint _
                    R * Cos(theta), _
                    theta * 0.8, _
                    R * Sin(theta)
            Next theta

        Case 4  ' Semicircle.
            R = 2
            dtheta = PI / 10
            TheExtrusion.AddPathPoint 0, 0, 0
            For theta = dtheta To PI Step dtheta
                TheExtrusion.AddPathPoint _
                    R * Sin(theta), _
                    R * (1 - Cos(theta)), _
                    0
            Next theta

        Case 5  ' Circle.
            R = 2
            dtheta = PI / 10
            TheExtrusion.AddPathPoint 0, 0, 0
            For theta = dtheta To 2 * PI - dtheta + 0.01 Step dtheta
                TheExtrusion.AddPathPoint _
                    R * Sin(theta), _
                    R * (1 - Cos(theta)), _
                    0
            Next theta
            TheExtrusion.AddPathPoint 0, 0, 0
    End Select
End Sub
' ************************************************
' Create the selected curve.
' ************************************************
Sub CreateCurve()
Dim R As Single
Dim dtheta As Single
Dim theta As Single
    Select Case CurveNum
        Case 0  ' Square.
            TheExtrusion.AddCurvePoint -2, 0, -2
            TheExtrusion.AddCurvePoint -2, 0, 2
            TheExtrusion.AddCurvePoint 2, 0, 2
            TheExtrusion.AddCurvePoint 2, 0, -2
            TheExtrusion.AddCurvePoint -2, 0, -2
        Case 1  ' Rectangle.
            TheExtrusion.AddCurvePoint -0.5, 0, -2
            TheExtrusion.AddCurvePoint -0.5, 0, 2
            TheExtrusion.AddCurvePoint 0.5, 0, 2
            TheExtrusion.AddCurvePoint 0.5, 0, -2
            TheExtrusion.AddCurvePoint -0.5, 0, -2

        Case 2  ' Semicircle.
            R = 2
            dtheta = PI / 10
            TheExtrusion.AddCurvePoint R, 0, 0
            For theta = dtheta To PI Step dtheta
                TheExtrusion.AddCurvePoint _
                    R * Cos(theta), 0, R * Sin(theta)
            Next theta

        Case 3, 4   ' Circle, small circle.
            If CurveNum = 3 Then
                R = 2
                dtheta = PI / 10
            Else
                R = 0.5
                dtheta = PI / 4
            End If
            TheExtrusion.AddCurvePoint R, 0, 0
            For theta = dtheta To 2 * PI - dtheta + 0.1 Step dtheta
                TheExtrusion.AddCurvePoint _
                    R * Cos(theta), 0, R * Sin(theta)
            Next theta
            TheExtrusion.AddCurvePoint R, 0, 0

        Case 5  ' Sine wave.
            R = 2
            dtheta = PI / 10
            theta = -PI / 2
            TheExtrusion.AddCurvePoint _
                R * Sin(theta), 0, 2 * theta
            For theta = -PI / 2 + dtheta To PI / 2 Step dtheta
                TheExtrusion.AddCurvePoint _
                    R * Sin(theta), 0, 2 * theta
            Next theta

    End Select
End Sub
Sub WaitEnd()
    MousePointer = vbDefault
End Sub
Sub WaitStart()
    MousePointer = vbHourglass
    DoEvents
End Sub
' ************************************************
' Create the extruded data and display it.
' ************************************************
Private Sub CmdExtrude_Click()
Dim pline As ObjPolyline
    ' If we currently have an APF file loaded,
    ' restore default settings.
    If CurveNum > 5 Then
        CurveChoice(0).value = True
        PathChoice(0).value = True
    End If
    WaitStart
    Set ThePicture = New ObjPicture
    Set TheExtrusion = New ObjExtrusion
    ThePicture.objects.Add TheExtrusion
    CreateCurve
    CreatePath
    TheExtrusion.Extrude
    If ShowAxesCheck.value = vbChecked Then
        Set pline = New ObjPolyline
        ThePicture.objects.Add pline
        pline.AddSegment 0, 0, 0, 5, 0, 0
        pline.AddSegment 0, 0, 0, 0, 5, 0
        pline.AddSegment 0, 0, 0, 0, 0, 5
    End If
    DrawData Pict
    Pict.SetFocus
End Sub
Private Sub CurveChoice_Click(Index As Integer)
    CurveNum = Index
    Pict.SetFocus
End Sub
' *******************************************************
' Rotate the points in the cube and draw the cube.
' *******************************************************
Private Sub DrawData(pic As Object)
Dim x As Single
Dim y As Single
Dim z As Single
Dim S(1 To 4, 1 To 4) As Single
Dim t(1 To 4, 1 To 4) As Single
Dim ST(1 To 4, 1 To 4) As Single
Dim PST(1 To 4, 1 To 4) As Single
    MousePointer = vbHourglass
    Refresh
    ' Prevent overflow errors when drawing lines
    ' too far out of bounds.
    On Error Resume Next
    ' Scale and translate so it looks OK in pixels.
    m3Scale S, 35, -35, 1
    m3Translate t, 180, 250, 0
    m3MatMultiplyFull ST, S, t
    m3MatMultiplyFull PST, Projector, ST
    ' Transform the points.
    ThePicture.ApplyFull PST
    ' Display the data.
    pic.Cls
    ThePicture.Draw pic, EyeR
    pic.Refresh
    ' Display the viewnig parameters.
    ShowViewingParameters
    MousePointer = vbDefault
End Sub
Sub ShowViewingParameters()
    ShowingParameters = True
    RText.Text = Format$(EyeR, "0.0000")
    ThetaText.Text = Format$(EyeTheta, "0.0000")
    PhiText.Text = Format$(EyePhi, "0.0000")
    RText.Refresh
    ThetaText.Refresh
    PhiText.Refresh
    ShowingParameters = False
End Sub
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    Select Case KeyCode
        Case vbKeyLeft
            EyeTheta = EyeTheta - dtheta

        Case vbKeyRight
            EyeTheta = EyeTheta + dtheta

        Case vbKeyUp
            EyePhi = EyePhi - Dphi

        Case vbKeyDown
            EyePhi = EyePhi + Dphi

        Case Else
            Exit Sub
    End Select
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
    DrawData Pict
End Sub
Private Sub Form_KeyPress(KeyAscii As Integer)
    Select Case KeyAscii
        Case Asc("+")
            EyeR = EyeR + Dr

        Case Asc("-")
            EyeR = EyeR - Dr

        Case Else
            Exit Sub
    End Select
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
    DrawData Pict
End Sub
Private Sub Form_Load()
    ' Initialize the eye position.
    EyeR = 10
    EyeTheta = PI * 0.2
    EyePhi = PI * 0.1
    ' Initialize the projection transformation.
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
End Sub
Private Sub mnuFileExit_Click()
    Unload Me
End Sub
Private Sub mnuFileLoad_Click()
Dim fname As String
Dim filenum As Integer
Dim txt As String
Dim Xmin As Single
Dim ymin As Single
Dim xmax As Single
Dim ymax As Single
    ' Allow the user to pick a file.
    On Error Resume Next
    LoadDialog.filename = "*.APF"
    LoadDialog.ShowOpen
    If Err.Number = cdlCancel Then
        Unload LoadDialog
        Exit Sub
    ElseIf Err.Number <> 0 Then
        Unload LoadDialog
        Beep
        MsgBox "Error selecting file.", , vbExclamation
        Exit Sub
    End If
    On Error GoTo 0
    fname = LoadDialog.filename
    LoadDialog.InitDir = Left$(fname, Len(fname) _
        - Len(LoadDialog.FileTitle) - 1)
    ' Clear the picture.
    Set ThePicture = Nothing
    ' Open the file.
    filenum = FreeFile
    Open fname For Input As #filenum
    ' Make sure it's an Object Picture File.
    Input #filenum, txt
    If txt <> "3D APF PICTURE" Then
        Close filenum
        Beep
        MsgBox "Error reading file """ & fname & """.", , vbExclamation
        Exit Sub
    End If
    ' Read the picture.
    MousePointer = vbHourglass
    DoEvents
    Set ThePicture = New ObjPicture
    ThePicture.FileInput filenum
    ' Close the file.
    Close filenum
    ' Refresh the display.
    DrawData Pict
    ' Deselect all the option buttons.
    For CurveNum = 0 To 5
        If CurveChoice(CurveNum).value Then _
            CurveChoice(CurveNum).value = False
    Next CurveNum
    For PathNum = 0 To 5
        If PathChoice(PathNum).value Then _
            PathChoice(PathNum).value = False
    Next PathNum
    MousePointer = vbDefault
End Sub
Private Sub mnuFileSaveAs_Click()
Dim fname As String
Dim filenum As Integer
    ' Allow the user to pick a file.
    On Error Resume Next
    LoadDialog.filename = "*.APF"
    LoadDialog.Flags = cdlOFNOverwritePrompt + cdlOFNHideReadOnly
    LoadDialog.ShowSave
    If Err.Number = cdlCancel Then
        Unload LoadDialog
        Exit Sub
    ElseIf Err.Number <> 0 Then
        Unload LoadDialog
        Beep
        MsgBox "Error selecting file.", , vbExclamation
        Exit Sub
    End If
    On Error GoTo 0
    fname = LoadDialog.filename
    LoadDialog.InitDir = Left$(fname, Len(fname) _
        - Len(LoadDialog.FileTitle) - 1)
    ' Open the file.
    filenum = FreeFile
    Open fname For Output As #filenum
    ' Write the picture.
    ThePicture.FileWrite filenum
    ' Close the file.
    Close filenum
End Sub
Private Sub PathChoice_Click(Index As Integer)
    PathNum = Index
    Pict.SetFocus
End Sub
Private Sub PhiText_Change()
    If ShowingParameters Then Exit Sub
    EyePhi = CSng(PhiText.Text)
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
    DrawData Pict
End Sub
Private Sub RText_Change()
    If ShowingParameters Then Exit Sub
    EyeR = CSng(RText.Text)
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
    DrawData Pict
End Sub
Private Sub ShowAxesCheck_Click()
    CmdExtrude_Click
    Pict.SetFocus
End Sub
Private Sub ThetaText_Change()
    If ShowingParameters Then Exit Sub
    EyeTheta = CSng(ThetaText.Text)
    m3PProject Projector, m3Perspective, EyeR, EyePhi, EyeTheta, FocusX, FocusY, FocusZ, 0, 1, 0
    DrawData Pict
End Sub